m4_define([law_version_major], [2])
m4_define([law_version_minor], [5])
m4_define([law_version_micro], [1])
m4_define([law_series], [law_version_major.law_version_minor])
m4_define([law_version], [law_version_major.law_version_minor.law_version_micro])

AC_INIT([libabiword],[law_version],[http://www.abisource.com/])
AM_INIT_AUTOMAKE
AC_CONFIG_HEADERS(config.h)

#
# Tests
#

AC_PROG_CC
AC_PROG_CXX
AC_PROG_INSTALL
AC_DISABLE_STATIC
AC_PROG_LIBTOOL

#
# Args
#

AC_ARG_WITH([source], 
	[AS_HELP_STRING([--with-source], [path to the abiword source tree])], 
[
	law_cv_src="${withval}"
],[
	law_cv_src=".${top_srcdir}/../abiword"
])

law_cv_gcc_pch="no"
AC_ARG_ENABLE([pch], 
	[AS_HELP_STRING([--enable-pch], [use gcc4 precompiled headers])], 
[
	law_cv_gcc_pch="${enableval}"
])

# pangoxft seems only needed with pch
deps_pkgs="
  enchant >= 1.2.0
  fribidi >= 0.10.4
  wv-1.0 >= 1.2.0
  pangoxft >= 1.2.0
  gtk+-2.0 >= 2.6.0
  libglade-2.0 >= 2.0.0
  libgnomeprintui-2.2 >= 2.2.0
  libgoffice-0.4
"

PKG_CHECK_MODULES(DEPS,[$deps_pkgs])
AC_SUBST([DEPS_CFLAGS])
AC_SUBST([DEPS_LIBS])

BASE_CPPFLAGS='\
  -include ${top_builddir}/config.h'
AC_SUBST([BASE_CPPFLAGS])

AF_CPPFLAGS='\
  ${BASE_CPPFLAGS} \
  -I${top_srcdir}/src/af/ev/unix \
  -I${top_srcdir}/src/af/ev/xp \
  -I${top_srcdir}/src/af/gr/unix \
  -I${top_srcdir}/src/af/gr/xp \
  -I${top_srcdir}/src/af/util/unix \
  -I${top_srcdir}/src/af/util/xp \
  -I${top_srcdir}/src/af/xap/unix \
  -I${top_srcdir}/src/af/xap/xp \
  -I${top_srcdir}/src/other/spell/xp'
AC_SUBST([AF_CPPFLAGS])

TEXT_CPPFLAGS='\
  ${AF_CPPFLAGS} \
  -I${top_srcdir}/src/text/fmt/unix \
  -I${top_srcdir}/src/text/fmt/xp \
  -I${top_srcdir}/src/text/ptbl/xp'
AC_SUBST([TEXT_CPPFLAGS])

IMPEXP_CPPFLAGS='\
  ${TEXT_CPPFLAGS} \
  -I${top_srcdir}/src/wp/impexp/unix \
  -I${top_srcdir}/src/wp/impexp/xp'
AC_SUBST([IMPEXP_CPPFLAGS])

WP_CPPFLAGS='\
  ${IMPEXP_CPPFLAGS} \
  -I${top_srcdir}/src/wp/ap/unix \
  -I${top_srcdir}/src/wp/ap/xp'
AC_SUBST([WP_CPPFLAGS])

#
# Settings
#

AM_CONDITIONAL([ENABLE_GCC_PCH], test "x${law_cv_gcc_pch}" = "xyes")

#
# abiword compat settings
# cut down over the time
#

ABIWORD_SERIES="law_series"
AC_DEFINE_UNQUOTED([ABIWORD_SERIES], [ "${ABIWORD_SERIES}" ], [major.minor])
AC_SUBST(ABIWORD_SERIES)
AC_SUBST(ABIWORD_DATADIR,    "${datadir}/${PACKAGE_NAME}-${ABIWORD_SERIES}")
AC_SUBST(ABIWORD_GLADEDIR,   "${ABIWORD_DATADIR}/glade")
AC_SUBST(ABIWORD_HEADERSDIR, "${includedir}/${PACKAGE_NAME}-${ABIWORD_SERIES}")
AC_SUBST(ABIWORD_LIBDIR,     "${libdir}/${PACKAGE_NAME}-${ABIWORD_SERIES}")
AC_SUBST(ABIWORD_PLUGINSDIR, "${ABIWORD_LIBDIR}/plugins")

# put all deps on a single line for the .pc file
ABIWORD_REQUIRED_PKGS=
for dep in `echo ${deps_pkgs}`; do
	ABIWORD_REQUIRED_PKGS="${ABIWORD_REQUIRED_PKGS} ${dep}"
done
AC_SUBST(ABIWORD_REQUIRED_PKGS)

AC_DEFINE([XP_UNIX_TARGET_GTK], [1], [building the gtk version])
AC_DEFINE([HAVE_ENCHANT], [1], [use Dom's enchanting spell checker abstraction library])
AC_DEFINE([ABI_SCANDIR_SELECT_QUALIFIER], [const], [Define to const if scandir's select function requires it, empty otherwise])

AM_CONDITIONAL([NOSPLASH], true)
AM_CONDITIONAL([SCRIPT], false)



AC_OUTPUT(
  libabiword.pc
  Makefile
  src/Makefile
  src/af/Makefile
  src/af/ev/Makefile
  src/af/ev/unix/Makefile
  src/af/ev/xp/Makefile
  src/af/gr/Makefile
  src/af/gr/unix/Makefile
  src/af/gr/xp/Makefile
  src/af/util/Makefile
  src/af/util/unix/Makefile
  src/af/util/xp/Makefile
  src/af/xap/Makefile
  src/af/xap/unix/Makefile
  src/af/xap/xp/Makefile
  src/other/Makefile
  src/other/spell/Makefile
  src/other/spell/xp/Makefile
  src/text/Makefile
  src/text/fmt/Makefile
  src/text/fmt/unix/Makefile
  src/text/fmt/xp/Makefile
  src/text/ptbl/Makefile
  src/text/ptbl/xp/Makefile
  src/wp/Makefile
  src/wp/ap/Makefile
  src/wp/ap/unix/Makefile
  src/wp/ap/xp/Makefile
  src/wp/impexp/Makefile
  src/wp/impexp/unix/Makefile
  src/wp/impexp/xp/Makefile
  user/Makefile
  user/wp/Makefile
  user/wp/strings/Makefile
  user/wp/templates/Makefile
)

echo "
Configuration:
  source tree:          ${law_cv_src}
  precompiled headers   ${law_cv_gcc_pch}
"