dnl= ##########################################################################
dnl= # abiword-plugins: autogen.sh header
dnl= # this file is executed as a shell script
dnl= 
dnl= # 1. abi_plugin_macro is the name of the main macro defined here:
dnl= abi_plugin_macro="ABIPGN_MHT"
dnl= 
dnl= # 2. abi_plugin_files is the list of files that configure must generate:
dnl= abi_plugin_files="GNUmakefile xp/GNUmakefile"
dnl= 
dnl= # 3. abi_plugin_desc is a short description of the plugin
dnl= abi_plugin_desc="Plugin to enable import of Multipart HTML documents"
dnl=
dnl= # 4. abi_plugin_enable - whether plugin should be enabled by default 
dnl= abi_plugin_enable="yes"
dnl=
dnl= return
dnl= ##########################################################################

AC_DEFUN([ABIPGN_MHT],[

_abi_cppflags_save="$CPPFLAGS"
_abi_ldflags_save="$LDFLAGS"

ABI_MHT_CPPFLAGS=""
ABI_MHT_LDFLAGS=""

# Checks for libraries.
# Checks for header files.

abi_plugin_disable=no

AC_ARG_WITH(inter7eps,[  --with-inter7eps=DIR     inter7 EPS library in DIR],[
	if test "x$withval" = "xno"; then
		ABI_PLUGIN_REPORT([mht: inter7 EPS support disabled])
		abi_plugin_disable=yes
	elif test "x$withval" != "xyes"; then
		ABI_MHT_CPPFLAGS="-I$withval/include/eps"
		ABI_MHT_LDFLAGS="-L$withval/lib"
		CPPFLAGS="$CPPFLAGS -I$withval/include/eps"
		LDFLAGS="$LDFLAGS -L$withval/lib"
	else
		ABI_MHT_CPPFLAGS="-I/usr/include/eps"
		CPPFLAGS="$CPPFLAGS -I/usr/include/eps"
	fi
],[	ABI_MHT_CPPFLAGS="-I/usr/include/eps"
	CPPFLAGS="$CPPFLAGS -I/usr/include/eps"
])

if test $abi_plugin_disable != yes; then
	AC_CHECK_HEADER(mime.h,[
		ABI_PLUGIN_REPORT([mht: okay])
		ABI_MHT_CPPFLAGS="$ABI_MHT_CPPFLAGS"
		ABI_MHT_LDFLAGS="$ABI_MHT_LDFLAGS -leps"
	],[	ABI_PLUGIN_REPORT([mht: error - inter7 EPS headers not found])
		ABI_PLUGIN_REPORT([mht:         http://www.inter7.com/eps/])
		abi_plugin_disable=yes
	])
fi
if test $abi_plugin_disable = yes; then
	ABI_MHT_CPPFLAGS=""
	ABI_MHT_LDFLAGS=""
fi

AC_SUBST(ABI_MHT_CPPFLAGS)
AC_SUBST(ABI_MHT_LDFLAGS)

CPPFLAGS="$_abi_cppflags_save"
LDFLAGS="$_abi_ldflags_save"
])