dnl= ##########################################################################
dnl= # abiword-plugins: autogen.sh header
dnl= # this file is executed as a shell script
dnl= 
dnl= # 1. abi_plugin_macro is the name of the main macro defined here:
dnl= abi_plugin_macro="ABIPGN_OPENWRITER"
dnl= 
dnl= # 2. abi_plugin_files is the list of files that configure must generate:
dnl= abi_plugin_files="GNUmakefile xp/GNUmakefile"
dnl= 
dnl= # 3. abi_plugin_desc is a short description of the plugin
dnl= abi_plugin_desc="Plugin to allow abiword to read/write OpenWriter and StarWriter documents"
dnl=
dnl= # 4. abi_plugin_enable - whether plugin should be enabled by default 
dnl= abi_plugin_enable="no"
dnl=
dnl= return
dnl= ##########################################################################

dnl This plugin is barely functional and needs -fpermissive or like to build
dnl (?? TODO FIXME ??)

AC_DEFUN([ABIPGN_OPENWRITER],[

_abi_cppflags_save="$CPPFLAGS"
_abi_ldflags_save="$LDFLAGS"

ABI_OPENWRITER_CPPFLAGS=""
ABI_OPENWRITER_LDFLAGS=""

# Checks for libraries.
# Checks for header files.

AC_ARG_WITH(zipios,[  --with-zipios=DIR       zipios++ library in DIR],[
	if [ test "x$withval" = "xno" ]; then
		AC_MSG_ERROR([* * * zipios++ library required to build this plugin * * *])
	elif [ test "x$withval" != "xyes" ]; then
		CPPFLAGS="$CPPFLAGS -I$withval/include"
		ABI_OPENWRITER_CPPFLAGS="-I$withval/include"
		ABI_OPENWRITER_LDFLAGS="-L$withval/lib"
	fi
])

AC_LANG_CPLUSPLUS

zipios_headers=yes
AC_CHECK_HEADER(zipios++/zipios-config.h,  ,zipios_headers=no)
AC_CHECK_HEADER(zipios++/zipfile.h,        ,zipios_headers=no)
AC_CHECK_HEADER(zipios++/meta-iostreams.h, ,zipios_headers=no)
AC_CHECK_HEADER(zipios++/fcollexceptions.h,,zipios_headers=no)
AC_CHECK_HEADER(zipios++/zipinputstream.h, ,zipios_headers=no)
AC_CHECK_HEADER(zipios++/zipoutputstream.h,,zipios_headers=no)
if [ test $zipios_headers = no ]; then
        ABI_PLUGIN_REPORT([OpenWriter: error - can't find zipios++ header(s)])
	abi_plugin_disable=yes
else
	ABI_PLUGIN_REPORT([OpenWriter: okay])
fi

AC_LANG_C

if test $abi_plugin_disable = no; then
	ABI_OPENWRITER_LDFLAGS="$ABI_OPENWRITER_LDFLAGS -lzipios -lz"
fi

AC_SUBST(ABI_OPENWRITER_CPPFLAGS)
AC_SUBST(ABI_OPENWRITER_LDFLAGS)

CPPFLAGS="$_abi_cppflags_save"
LDFLAGS="$_abi_ldflags_save"
])